Merge website and CMake to Meson transition

Building a website to structure and deploy the artifacts was planned and
requires a well set-up build system to handle all the file paths targets
and dependencies.

Since multiple CMake Zephyr builds are required for the application
firmware, bootloader firmware and the native_sim application firmware
simulation CMake external project was used.

Since this generates a build tree with a confusing structure Meson was
evaluated.

Finally the Meson build system was a good fit as top-level build system
and allows external projects as an experimental feature if they can
configure a Make-based build system which is given for Zephyr.

1 files changed, 45 insertions, 0 deletions

diff --git a/fw/app/meson.build b/fw/app/meson.build
new file mode 100644
index 0000000..97c17f1
--- /dev/null
+++ b/fw/app/meson.build
@@ -0,0 +1,45 @@
+external_project = import('unstable-external_project')
+
+application_source = meson.current_source_dir()
+
+external_project.add_project(
+  configure_zephyr,
+  configure_options: [
+    '--source-tree', application_source,
+    '--build-tree', meson.current_build_dir() / 'build',
+    '--board', board,
+    '--zephyr-base', zephyr,
+    '--zephyr-modules', ';'.join(zephyr_modules),
+  ],
+  verbose: true,
+)
+
+application = custom_target(
+  'application',
+  output: ['application.bin'],
+  command: [
+    build_zephyr,
+    '--build-tree', meson.current_build_dir() / 'build',
+    '--binary-name', 'zephyr.bin',
+    '--target-name', 'application.bin',
+  ],
+)
+
+application_signed = custom_target(
+  'application_signed',
+  output: ['application.signed.bin'],
+  command: [
+    imgtool,
+    'sign',
+    '--version', '0.0.0',
+    '--header-size', '0x200',
+    '--slot-size', '0xc0000',
+    '--key', signing_key,
+    meson.current_build_dir() / 'application.bin',
+    meson.current_build_dir() / 'application.signed.bin',
+  ],
+  build_by_default: true,
+  depends: application,
+  install: true,
+  install_dir: 'website/static',
+)