From 2e06463fa8f19fb04c9d71dc64a6c2e19317c44a Mon Sep 17 00:00:00 2001
From: xengineering <me@xengineering.eu>
Date: Sat, 20 Dec 2025 16:36:58 +0100
Subject: sia-server: Package version 0.1.0

---
 sia-server/PKGBUILD | 41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 sia-server/PKGBUILD

diff --git a/sia-server/PKGBUILD b/sia-server/PKGBUILD
new file mode 100644
index 0000000..0c8f26a
--- /dev/null
+++ b/sia-server/PKGBUILD
@@ -0,0 +1,41 @@
+# Maintainer: xengineering <me@xengineering.eu>
+pkgname=sia-server
+pkgver=0.1.0
+pkgrel=1
+pkgdesc="IoT backend server"
+arch=('x86_64')
+url="https://xengineering.eu/git/${pkgname}"
+license=('AGPL')
+depends=('mosquitto')
+makedepends=('git' 'go' 'meson' 'tar')
+backup=("etc/${pkgname}/config.json")
+source=("git+https://cgit.xengineering.eu/${pkgname}#tag=v${pkgver}?signed")
+sha256sums=('SKIP')
+
+validpgpkeys=(
+	'A13B258878787F943F6C68F00FD1F84233FA8900'  # xengineering <me@xengineering.eu>
+)
+
+build() {
+	cd "${srcdir}/${pkgname}"
+	export CGO_CPPFLAGS="${CPPFLAGS}"
+	export CGO_CFLAGS="${CFLAGS}"
+	export CGO_CXXFLAGS="${CXXFLAGS}"
+	export CGO_LDFLAGS="${LDFLAGS}"
+	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+	meson setup build
+	meson compile -C build
+}
+
+check() {
+	cd "${srcdir}/${pkgname}"
+	meson 'test' -C build
+}
+
+package() {
+	cd "${srcdir}/${pkgname}"
+	install -D -m 755 "${srcdir}/${pkgname}/build/${pkgname}-linux-amd64" "${pkgdir}/usr/bin/${pkgname}"
+	install -D -m 644 "${srcdir}/${pkgname}/build/configs/default.json" "${pkgdir}/etc/${pkgname}/config.json"
+	install -D -m 644 "${srcdir}/${pkgname}/build/systemd/sia-server.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
+	install -D -m 644 "${srcdir}/${pkgname}/build/systemd/sia-server-sysuser.conf" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
+}
-- 
cgit v1.2.3-70-g09d2