From b6a803b02a0a63ebe20ca1fe7fe47203f9fba089 Mon Sep 17 00:00:00 2001
From: xengineering <me@xengineering.eu>
Date: Sun, 24 May 2026 11:04:37 +0200
Subject: finserv: Add package

---
 finserv/PKGBUILD | 40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 finserv/PKGBUILD

(limited to 'finserv')

diff --git a/finserv/PKGBUILD b/finserv/PKGBUILD
new file mode 100644
index 0000000..e1fc0ed
--- /dev/null
+++ b/finserv/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: xengineering <me@xengineering.eu>
+pkgname=finserv
+pkgver='0.1.0'
+pkgrel=1
+pkgdesc="Personal finances server"
+arch=('x86_64')
+url="https://xengineering.eu/git/${pkgname}"
+license=('MPL-2.0')
+makedepends=('coreutils' 'git' 'meson' 'ninja' 'go' 'hugo')
+source=("git+https://cgit.xengineering.eu/${pkgname}#tag=v${pkgver}?signed")
+sha256sums=('SKIP')
+
+validpgpkeys=(
+	'A13B258878787F943F6C68F00FD1F84233FA8900'  # xengineering <me@xengineering.eu>
+)
+
+prepare() {
+	cd "${srcdir}/${pkgname}"
+	git submodule init
+	git submodule update
+}
+
+build() {
+	cd "${srcdir}/${pkgname}"
+	export CGO_CPPFLAGS="${CPPFLAGS}"
+	export CGO_CFLAGS="${CFLAGS}"
+	export CGO_CXXFLAGS="${CXXFLAGS}"
+	export CGO_LDFLAGS="${LDFLAGS}"
+	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+	meson setup build
+	meson compile -C build
+}
+
+package() {
+	cd "${srcdir}/${pkgname}"
+	install -D -m 755 "${srcdir}/${pkgname}/build/${pkgname}-linux-amd64" "${pkgdir}/usr/bin/${pkgname}"
+	install -D -m 644 "${srcdir}/${pkgname}/systemd/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
+	install -D -m 644 "${srcdir}/${pkgname}/systemd/sysuser.conf" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
+	install -D -m 644 "${srcdir}/${pkgname}/systemd/${pkgname}.tmpfile.d" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
+}
-- 
cgit v1.3.1