# Maintainer: xengineering <me@xengineering.eu>
pkgname=webiot
pkgver=0.1.0
pkgrel=2
pkgdesc="Lightweight IoT web server"
arch=('x86_64' 'aarch64')
url="https://xengineering.eu/git/webiot"
license=('AGPL')
makedepends=('coreutils' 'go')
backup=('etc/webiot/config.json')
source=("git+https://cgit.xengineering.eu/${pkgname}#tag=$pkgver?signed")
sha256sums=('SKIP')

validpgpkeys=(
	'A13B258878787F943F6C68F00FD1F84233FA8900'  # xengineering <me@xengineering.eu>
)

prepare() {
	cd "${srcdir}/${pkgname}"
	git submodule init
	git submodule update
}

build() {
	cd "${srcdir}/${pkgname}"
	export CGO_CPPFLAGS="${CPPFLAGS}"
	export CGO_CFLAGS="${CFLAGS}"
	export CGO_CXXFLAGS="${CXXFLAGS}"
	export CGO_LDFLAGS="${LDFLAGS}"
	export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
	go build -o "build/${pkgname}" *.go
}

package() {
	cd "${srcdir}"
	install -D -m 755 "${pkgname}/build/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
	install -D -m 644 "${pkgname}/config/default.json" "${pkgdir}/etc/${pkgname}/config.json"
	install -D -m 644 "../${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
	install -D -m 644 "../sysuser.conf" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
}